AC_INIT([Harriman-Peikoff Project], [0.00.000],
    [latentprion@gmail.com],
    [harikoff],
    [github.com/latentprion/harikoff])

AC_CONFIG_SRCDIR([hcore/mind.cpp])
AC_CONFIG_AUX_DIR([autotools-aux])
AC_CONFIG_MACRO_DIR([m4])

AM_INIT_AUTOMAKE([foreign -Wall -Werror])

# Set the mind's quantized virtual oscillator period in milliseconds.
# Default value is 33 ms, user override via MIND_VOSCILLATOR_PERIOD_MS.
# Check if MIND_VOSCILLATOR_PERIOD_MS is a valid positive integer
AC_ARG_VAR([MIND_VOSCILLATOR_PERIOD_MS], m4_normalize([
    Mind's virtual osc clock rate. Must be a positive integer, default value 33
]))
AS_IF([test -z "${MIND_VOSCILLATOR_PERIOD_MS}"], [MIND_VOSCILLATOR_PERIOD_MS=33])
AS_IF([! test "${MIND_VOSCILLATOR_PERIOD_MS}" -eq "${MIND_VOSCILLATOR_PERIOD_MS}" 2>/dev/null ||
    test "${MIND_VOSCILLATOR_PERIOD_MS}" -le 0 2>/dev/null], [
    AC_MSG_ERROR([MIND_VOSCILLATOR_PERIOD_MS must be a positive integer > 0.])
])

AC_DEFINE_UNQUOTED([CONFIG_MIND_VOSCILLATOR_PERIOD_MS],
    [${MIND_VOSCILLATOR_PERIOD_MS}],
    [Period of the mind virtual oscillator in milliseconds])
AC_COMPUTE_INT(
    [MIND_VOSCILLATOR_FREQ_MS], [1000 / ${MIND_VOSCILLATOR_PERIOD_MS}], [],
    [AC_MSG_ERROR([Failed to compute the mind's virtual oscillator frequency.])])
AC_DEFINE_UNQUOTED([CONFIG_MIND_VOSCILLATOR_FREQ_MS],
    [${MIND_VOSCILLATOR_FREQ_MS}],
    [Frequency of the mind virtual oscillator in milliseconds])

m4_include([m4/ac_prog_flex.m4])
m4_include([m4/ac_prog_bison.m4])
AC_PROG_CC
AC_PROG_CXX
AC_PROG_RANLIB
AM_PROG_AR
AC_PROG_LEX(noyywrap)
AC_PROG_YACC
AS_IF([test -z "${LEX}" || test -z "${YACC}"], [
    AC_MSG_ERROR([LEX and YACC must both be available in PATH.])
])

AM_CPPFLAGS=m4_normalize(["-I\"\$(top_srcdir)/include\""])

AC_SUBST([AM_CPPFLAGS])
AC_SUBST([YACC])
AC_SUBST([LEX])

AC_CONFIG_HEADERS([include/config.h])
AC_CONFIG_FILES([
    Makefile hcore/Makefile
    hcore/deviceManager/Makefile
])

AC_CONFIG_COMMANDS_POST([
    AC_MSG_NOTICE([${PACKAGE_NAME} ${PACKAGE_VERSION} configuration:])
    AC_MSG_NOTICE(m4_normalize([* MIND_VOSCILLATOR_PERIOD_MS:
        ${MIND_VOSCILLATOR_PERIOD_MS} ms
        (freq: ${MIND_VOSCILLATOR_FREQ_MS} Hz)]))
])

AC_OUTPUT