%{
#include <vector>
#include <utility>
#include <string>
#include <cstring>
#include <cstdlib>
#include <stdexcept>
#include <memory>
#include <functional>
#include <user/senseDeviceSpec.h>
#include <deviceManager/deviceManager.h>

#ifndef yylex
/* We use different prefixes for the lexer and parser.
 * * Our lexer's prefix is deviceSpecl.
 * * Our parser's prefix is deviceSpecp.
 *
 * Yacc and Bison don't have a way to handle the scenario where the lexer has
 * a different prefix from the parser that they generate. They assume that the
 * lexer must have the same prefix as the parser they generate. So we just use
 * this #define below to override yacc/bison's presumed prefix for the lexer.
 */
#error "Yacc should have defined yylex as a preprocessor token, and we need to override it to tell yacc the name of our lex function."
#endif
#undef yylex
#define yylex deviceSpecllex

#ifdef yytext
#undef yytext
#endif
#define yytext deviceSpecltext

// Declare the symbols that our lexer will export.
int yylex(void);
extern char* yytext; // Declare yytext to access the current token text
void yyerror(const char *message)
{
    throw std::runtime_error(
        std::string("deviceSpec parser error: ")
            + std::string(message)
            + " at token: " + std::string(yytext));
}

%}

%union {
    char* str;
    char chr;
    smo::device::SenseDeviceSpec* sensorSpec;
    smo::device::InteroceptorDeviceSpec* interoceptorSpec;
    smo::device::ExtrospectorDeviceSpec* extrospectorSpec;
    std::vector<std::pair<std::string,std::string>>* paramVector;
    std::pair<std::string,std::string>* param;
}

%token <str> STRING
%token PIPE DOUBLE_PIPE LPAREN RPAREN
%token <chr> KEYWORD_SPECTYPE_ACTUATOR
%token <chr> KEYWORD_SPECTYPE_EXTROSPECTOR KEYWORD_SPECTYPE_INTEROSPECTOR
%token EQUALS    // Add new token for '='

%type <paramVector> params opt_params
%type <param> param
%type <sensorSpec> spec_body
%type <interoceptorSpec> interoceptor_spec
%type <extrospectorSpec> extrospector_spec

%%

file: /* NOTHING */
    | sensor_specs
    ;

sensor_specs:
    sensor_spec
    | sensor_specs DOUBLE_PIPE sensor_spec
    ;

sensor_spec:
    interoceptor_spec
    | extrospector_spec
    ;

interoceptor_spec:
    KEYWORD_SPECTYPE_INTEROSPECTOR PIPE spec_body {
        auto spec = std::make_shared<smo::device::InteroceptorDeviceSpec>(
            *static_cast<smo::device::InteroceptorDeviceSpec *>($3));

        spec->sensorType = $1;
        smo::device::DeviceManager::interoceptorDeviceSpecs.push_back(spec);
        smo::device::DeviceManager::senseDeviceSpecs.push_back(spec);

        delete $3;
    }
    ;

extrospector_spec:
    KEYWORD_SPECTYPE_EXTROSPECTOR PIPE spec_body {
        auto spec = std::make_shared<smo::device::ExtrospectorDeviceSpec>(
            *static_cast<smo::device::ExtrospectorDeviceSpec *>($3));

        spec->sensorType = $1;
        smo::device::DeviceManager::extrospectorDeviceSpecs.push_back(spec);
        smo::device::DeviceManager::senseDeviceSpecs.push_back(spec);

        delete $3;
    }
    ;

spec_body:
    STRING PIPE STRING LPAREN opt_params RPAREN PIPE STRING LPAREN opt_params RPAREN PIPE STRING {
        $$ = new smo::device::SenseDeviceSpec();
        $$->sensorType = '\0';
        $$->implexor = std::string($1);
        $$->api = std::string($3);
        $$->apiParams = std::move(*$5);
        $$->provider = std::string($8);
        $$->providerParams = std::move(*$10);
        $$->deviceSelector = std::string($13);
        delete $5;
        delete $10;
    }
    ;

opt_params:
    params
    | /* empty */ { $$ = new std::vector<std::pair<std::string,std::string>>(); }
    ;

params:
    param {
        $$ = new std::vector<std::pair<std::string,std::string>>();
        $$->push_back(*$1);
        delete $1;
    }
    | params PIPE param {
        $$ = $1;
        $$->push_back(*$3);
        delete $3;
    }
    ;

param:
    STRING {
        $$ = new std::pair<std::string,std::string>($1, "");
    }
    | STRING EQUALS {
        $$ = new std::pair<std::string,std::string>($1, "");
    }
    | STRING EQUALS STRING {
        $$ = new std::pair<std::string,std::string>($1, $3);
    }
    ;

%%